ASM杂项集合【802/绿宝石】

本站第一萌新 · 发表于 2020-5-8 15:42:25

本帖最后由本站第一萌新于 2020-6-8 13:07 编辑

使得精灵可以使用对应属性的野外技能（一下想不起名字了，理解就好）如杰尼龟可以使用潜水，鱼跃龙门，冲浪。
这个创意最初是来自于老外FBI的，但他的实现我没有去看。不过想来也应该大同小异吧
注意：有点小bug 普通属性精灵无法换位

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func AddFieldMoveToList
ldr r5, =0x08615D7E
mov r0, #100
mov r1, r10
mul r0, r1
mov r1, r9
add r0, r1
mov r1, #0xB
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
ldr r1, =0x08F186E0
mov r2, #0x1C
mul r0, r2
add r0, r1
ldrb r7, [r0, #6]
ldrb r1, [r0, #7]
mov r8, r1
ldr r4, =0x08E2B7C8
mov r6, #0
AddFieldMoveLoop:
lsl r0, r6, #1
ldrh r0, [r0, r5]
cmp r0, #0xE
beq AddFieldMoveLoopEnd
mov r1, #0xC
mul r1, r0
add r1, r4
ldrb r1, [r1, #2]
cmp r1, r7
beq AddToList
mov r2, r8
cmp r1, r2
beq AddToList
b PrepareNext
AddToList:
mov r2, #19
add r2, r6
ldr r0, =0x0203CEC4
ldr r0, [r0]
mov r1, r0
add r0, #0xF
add r1, #0x17
ldr r3, =(0x080A0944|1)
bl call_bx
PrepareNext:
add r6, #1
b AddFieldMoveLoop
AddFieldMoveLoopEnd:
ldr r3, =(0x081B34AA|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x081B3440
ldr r3, =(AddFieldMoveToList|1)
bx r3
.pool
.org 0x081B54F6
mov r0, #1 ;使得徽章检查失去作用。删去这块如果你不想要这个效果
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-9 15:53:36

本帖最后由本站第一萌新于 2021-7-23 10:00 编辑

命名界面支持中文输入
这个是花了一上午搞得。还有些bug，所以最好不要用或者请自行稍作修改
1.输入中文的时候好像没有检测是否超出最大字符数
2.输入的时候字符无法对其下划线。这个是因为它输出不是一连串输出而是一个一个字符输出的，我实在懒得新建一个全局变量用来记录什么地方是中文字符什么地方不是
3.中文字符删除不能一次删完，而是会变成一个其他字符，原理同上
由于代码过于庞大，所以上传为文件，请自行重命名为.asm文件
不过现在想来貌似用一个循环就能实现了，实在没有必要浪费这么多空间:(
修复版下载地址：https://share.weiyun.com/PIwjima3 PS：解决了上述bug。但由于时间原因，该版本代码仍存在较大优化空间

本站第一萌新 · 发表于 2020-5-10 09:12:14

修改pokemart脚本对应的函数，使得商店地址为0时随机生成商品（不会出现重要道具）
本例没有处理重复的问题，有兴趣的可以自行修改程序

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func NewSetItem
push {r4, lr}
ldr r1, =0x02039F60
mov r2, #0
strb r2, [r1, #0xC]
ldr r2, [r1, #8]
ldr r3, =0x0203F000
mov r1, #0
cmp r2, r3
bne CheckIsRandom
mov r1, #0
ClearItemLoop:
lsl r2, r1, #1
add r4, r2, r3
ldrh r2, [r4]
cmp r2, #0
beq CheckIsRandom
mov r2, #0
strh r2, [r4]
add r1, #1
b ClearItemLoop
CheckIsRandom:
cmp r0, #0
bne LoadItemToList
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r1, #10
ldr r3, =(0x082E7650|1)
bl call_bx
add r4, r0, #1
ldr r1, =0x02039F60
strb r4, [r1, #0xC]
mov r5, #0
GetRandomItemLoop:
cmp r5, r4
bge GetRandomItemLoopEnd
GetAgain:
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r1, #10
lsl r1, #6 ;0x280 改成你的版本的道具数
ldr r3, =(0x082E7650|1)
bl call_bx
add r0, #1
mov r6, r0
ldr r3, =(0x080D6C68|1)
bl call_bx
cmp r0, #5
beq GetAgain
ldr r1, =0x0203F000
lsl r2, r5, #1
strh r6, [r1, r2]
add r5, #1
b GetRandomItemLoop
GetRandomItemLoopEnd:
mov r0, #0
lsl r2, r5, #1
strh r0, [r1, r2]
mov r0, r1
mov r1, #1
LoadItemToList:
ldr r2, =0x02039F60
str r0, [r2, #8]
cmp r0, #0
bne NewSetItemBack
mov r1, #0
GetCountLoop:
lsl r0, r1, #1
ldrh r0, [r0, r2]
cmp r0, #0
beq GetCountLoopEnd
add r1, #1
b GetCountLoop
GetCountLoopEnd:
strb r1, [r2, #0xC]
NewSetItemBack:
pop {r4, pc}
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x080DFB58
ldr r3, =(NewSetItem|1)
bx r3
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-13 13:09:02

简易个体努力查看器
之前做过的东西。这个肯定是不如版主早期那个作品美观的，不过还是发出来做个记录
一样的和初始村蓝胖对话查看效果，如果想自己更改示例脚本也已经给出了

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.macro WindowTemplate, bg, tilemapLeft, tilemapTop, width, height, paletteNum, baseBlock
.align 2
.byte bg
.byte tilemapLeft
.byte tilemapTop
.byte width
.byte height
.byte paletteNum
.halfword baseBlock
.endmacro
.macro BgTemplate, bg, charBaseIndex, mapBaseIndex, screenSize, paletteMode, priority, baseTile
.align 4
.word (bg) | (charBaseIndex << 2) | (mapBaseIndex << 4) | (screenSize << 9) | (paletteMode << 11) | (priority << 12) | (baseTile << 14)
.endmacro
.macro FillBgTilemapBufferRect, bg, tileNum, x, y, width, height, pal
mov r0, width
str r0, [sp]
mov r0, height
str r0, [sp, #4]
mov r0, pal
str r0, [sp, #8]
mov r0, bg
ldr r1, =0x1A2
add r1, (tileNum - 0x1A2)
mov r2, x
mov r3, y
ldr r4, =(0x08002804|1)
bl call_bx2
.endmacro
.org 0x08F80000
.func MainFunc
push {lr}
ldr r0, =(CB2_Main|1)
ldr r3, =(0x08000540|1)
bl call_bx
ldr r3, =(0x08098E54|1)
bl call_bx
pop {pc}
.endfunc
.pool
.func CB2_Main
push {lr}
ldr r1, =0x030022C0
mov r2, #0x87
lsl r2, #3
add r1, r2
mov r0, #0
strb r0, [r1] ;gMain.state
ldr r3, =(0x080AC378|1)
bl call_bx
ldr r3, =(0x08085D34|1)
bl call_bx
ldr r0, =(CB2_ShowIVEV|1)
ldr r3, =(0x08000540|1)
bl call_bx
ldr r1, =0x030022C0
ldr r0, =(0x080861CC|1)
str r0, [r1, #8]
pop {pc}
.func CB2_ShowIVEV
push {r4-r7, lr}
mov r4, r8
push {r4}
add sp, #-12
ldr r1, =0x030022C0
mov r2, #0x87
lsl r2, #3
add r1, r2
ldrb r0, [r1] ;gMain.state
ldr r1, =Switch
lsl r0, #1
ldrh r0, [r0, r1]
add r0, pc
bx r0
SetVBlankCallback:
mov r0, #0
ldr r3, =(0x080006F0|1)
bl call_bx
b AddState
InitBgsAndWindows:
mov r3, #0xC0
ldr r2, =0x06017000
lsl r3, #19
ClearLoop:
mov r1, #0x80
lsl r1, #5
mov r12, r1
add r3, r12
cmp r3, r2
bne ClearLoop
mov r3, sp
add r2, r3, #6
ldr r3, =0x040000D4
str r2, [r3]
mov r2, #0xA0
lsl r2, #19
str r2, [r3, #4]
ldr r2, =0x81000200
str r2, [r3, #8]
mov r0, #0
ldr r3, =(0x080017BC|1)
bl call_bx
mov r0, #0
ldr r1, =sShowEVIVBgTemplates
mov r2, #2
ldr r3, =(0x080017E8|1)
bl call_bx
mov r0, #0
mov r1, #0
mov r2, #0
ldr r3, =(0x08001D04|1)
bl call_bx
mov r0, #0
mov r1, #0
mov r2, #0
ldr r3, =(0x08001E7C|1)
mov r0, #1
mov r1, #0
mov r2, #0
ldr r3, =(0x08001D04|1)
bl call_bx
mov r0, #1
mov r1, #0
mov r2, #0
ldr r3, =(0x08001E7C|1)
bl call_bx
ldr r0, =sShowEVIVWinTemplates
ldr r3, =(0x080031C0|1)
bl call_bx
ldr r3, =(0x080045B0|1)
bl call_bx
mov r0, #0
mov r1, #12
lsl r1, #10
add r1, #0x40
ldr r3, =(0x080010B4|1)
bl call_bx
mov r0, #0
ldr r3, =(0x08001B30|1)
bl call_bx
mov r0, #1
ldr r3, =(0x08001B30|1)
bl call_bx
b AddState
ResetData:
ldr r3, =(0x080A1A74|1)
bl call_bx
ldr r3, =(0x080B9FB8|1)
bl call_bx
ldr r3, =(0x080A8F50|1)
bl call_bx
ldr r3, =(0x08006974|1)
bl call_bx
b AddState
LoadBoxTiles:
ldr r0, =0x03005D90
ldr r0, [r0]
ldrb r0, [r0, #0x14]
lsr r0, #3
ldr r3, =(0x08098758|1)
bl call_bx
ldr r1, [r0]
mov r2, #0x90
lsl r2, #1
ldr r3, =0x1A2
mov r0, #1
ldr r4, =(0x08001944|1)
bl call_bx2
b AddState
LoadWindowPalette:
ldr r0, =0x0855C6A0
mov r1, #0
mov r2, #2
ldr r3, =(0x080A1938|1)
bl call_bx
ldr r0, =0x03005D90
ldr r0, [r0]
ldrb r0, [r0, #0x14]
lsr r0, #3
ldr r3, =(0x08098758|1)
bl call_bx
ldr r0, [r0, #4]
mov r1, #0x70
mov r2, #0x20
ldr r3, =(0x080A1938|1)
bl call_bx
b AddState
LoadTextPalette:
ldr r0, =0x0855C604
mov r1, #0x10
mov r2, #0x20
ldr r3, =(0x080A1938|1)
bl call_bx
b AddState
DrawAndPutControl:
mov r0, #1
ldr r3, =(0x0800378C|1)
bl call_bx
bl DrawTextControl
b AddState
WaitState:
b AddState
DrawAndPutMonIVEV:
mov r0, #0
ldr r3, =(0x0800378C|1)
bl call_bx
mov r0, #0
bl DrawMonIVEV
b AddState
FillBgTilemapBufferRects:
bl FillBgTilemap
b AddState
CreateSpritesAndTask:
ldr r0, =(Task_ShowIVEVFadeIn|1)
ldr r3, =(0x080A8FB0|1)
bl call_bx
mov r5, r0
ldr r2, =0x03005E00
mov r1, #40
mul r0, r1
add r2, r0
mov r0, #1
strh r0, [r2, #8] ;tMonId
ldr r0, =0x020244E9
ldrb r6, [r0]
ldr r0, =0x020244EC
mov r8, r0
mov r7, #0
CreateSpritesLoop:
cmp r7, r6
bge CreateSpritesLoopEnd
mov r0, r8
mov r1, #100
mul r1, r7
add r0, r1
mov r1, #0
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
str r0, [sp, #4]
mov r0, #1
str r0, [sp, #8]
str r0, [sp]
mov r0, r8
mov r1, #100
mul r1, r7
add r0, r1
mov r1, #0xB
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
mov r4, r0
ldr r3, =(0x080D2F68|1)
bl call_bx
mov r0, r4
ldr r2, =PoiX
ldrb r2, [r2, r7]
ldr r1, =(0x08007428|1)
mov r3, #0x10
ldr r4, =(0x080D2CC4|1)
bl call_bx2
ldr r1, =0x02020630
mov r2, #0x44
mul r2, r0
add r1, r2
ldrh r2, [r1, #4]
ldr r3, =0xF3FF
and r2, r3
strh r2, [r1, #4]
mov r1, r5
ldr r3, =0x03005E00
mov r2, #40
mul r1, r2
add r3, r1
add r3, #9
strb r0, [r3, r7]
add r7, #1
b CreateSpritesLoop
CreateSpritesLoopEnd:
ldrb r0, [r3]
ldr r1, =0x02020630
mov r2, #0x44
mul r2, r0
add r1, r2
ldr r0, =(0x080D3014|1)
str r0, [r1, #0x1C]
b AddState
FadeAndChangeCallBack:
mov r0, #0
str r0, [sp]
neg r0, r0
mov r1, #0
mov r2, #0x10
mov r3, #0
ldr r4, =(0x080A1AD4|1)
bl call_bx2
ldr r0, =(0x080BA4C8|1)
ldr r3, =(0x080006F0|1)
bl call_bx
ldr r0, =(0x080BA4B0|1)
ldr r3, =(0x08000540|1)
bl call_bx
AddState:
ldr r1, =0x030022C0
mov r0, #0x87
lsl r0, #3
add r1, r0
ldrb r0, [r1]
add r0, #1
strb r0, [r1]
add sp, #12
pop {r4}
mov r8, r4
pop {r4-r7, pc}
.endfunc
.pool
.func DrawTextControl
push {r4, lr}
add sp, #-12
mov r0, #1
mov r1, #17
ldr r3, =(0x08003C48|1)
bl call_bx
mov r0, #1
str r0, [sp]
mov r0, #0xFF
str r0, [sp, #4]
mov r0, #0
str r0, [sp, #8]
mov r0, #1
mov r1, #1
ldr r2, =gText_Control
mov r3, #8
ldr r4, =(0x080045D0|1)
bl call_bx2
mov r0, #1
mov r1, #3
ldr r3, =(0x08003658|1)
bl call_bx
add sp, #12
pop {r4, pc}
.endfunc
.pool
.func DrawMonIVEV
push {r4-r6, lr}
add sp, #-16
mov r5, r0
mov r0, #0
mov r1, #17
ldr r3, =(0x08003C48|1)
bl call_bx
mov r0, #32
str r0, [sp]
mov r0, #0xFF
str r0, [sp, #4]
mov r0, #0
str r0, [sp, #8]
mov r0, #0
mov r1, #1
ldr r2, =gText_Frame
mov r3, #8
ldr r4, =(0x080045D0|1)
bl call_bx2
ldr r0, =0x02021FC4
mov r1, #0xFF
strb r1, [r0]
ldr r0, =0x020244EC
mov r1, #100
mul r1, r5
add r5, r1, r0
mov r6, #0
BufferIVLoop:
cmp r6, #6
bge BufferIVLoopEnd
mov r0, r5
mov r1, #0x27
add r1, r6
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
mov r1, r0
add r0, sp, #12
mov r2, #2
mov r3, #3
ldr r4, =(0x08008CC0|1)
bl call_bx2
ldr r0, =0x02021FC4
add r1, sp, #12
ldr r3, =(0x08008BC0|1)
bl call_bx
ldr r0, =0x02021FC4
ldr r1, =gText_Blank
ldr r3, =(0x08008BC0|1)
bl call_bx
add r6, #1
b BufferIVLoop
BufferIVLoopEnd:
ldr r0, =0x02021FC4
ldr r1, =gText_LineFeed
ldr r3, =(0x08008BC0|1)
bl call_bx
mov r6, #0
BufferEVLoop:
cmp r6, #6
bge BufferEVLoopEnd
mov r0, r5
mov r1, #0x1A
add r1, r6
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
mov r1, r0
add r0, sp, #12
mov r2, #2
mov r3, #3
ldr r4, =(0x08008CC0|1)
bl call_bx2
ldr r0, =0x02021FC4
add r1, sp, #12
ldr r3, =(0x08008BC0|1)
bl call_bx
ldr r0, =0x02021FC4
ldr r1, =gText_Blank
ldr r3, =(0x08008BC0|1)
bl call_bx
add r6, #1
b BufferEVLoop
BufferEVLoopEnd:
mov r0, #48
str r0, [sp]
mov r0, #0xFF
str r0, [sp, #4]
mov r0, #0
str r0, [sp, #8]
mov r0, #0
mov r1, #1
ldr r2, =0x02021FC4
mov r3, #35
ldr r4, =(0x080045D0|1)
bl call_bx2
mov r0, #0
mov r1, #3
ldr r3, =(0x08003658|1)
bl call_bx
add sp, #16
pop {r4-r6, pc}
.endfunc
.pool
.func FillBgTilemap
push {r4, lr}
add sp, #-12
FillBgTilemapBufferRect 1, 0x1A2, 1, 0, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A3, 2, 0, 26, 1, 7
FillBgTilemapBufferRect 1, 0x1A4, 28, 0, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A5, 1, 1, 1, 14, 7
FillBgTilemapBufferRect 1, 0x1A7, 28, 1, 1, 14, 7
FillBgTilemapBufferRect 1, 0x1A8, 1, 15, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A9, 2, 15, 26, 1, 7
FillBgTilemapBufferRect 1, 0x1AA, 28, 15, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A2, 1, 16, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A3, 2, 16, 26, 1, 7
FillBgTilemapBufferRect 1, 0x1A4, 28, 16, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A5, 1, 17, 1, 2, 7
FillBgTilemapBufferRect 1, 0x1A7, 28, 17, 1, 2, 7
FillBgTilemapBufferRect 1, 0x1A8, 1, 19, 1, 1, 7
FillBgTilemapBufferRect 1, 0x1A9, 2, 19, 26, 1, 7
FillBgTilemapBufferRect 1, 0x1AA, 28, 19, 1, 1, 7
mov r0, #1
ldr r3, =(0x0800236C|1)
bl call_bx
add sp, #12
pop {r4, pc}
.endfunc
.pool
.func Task_ShowIVEVFadeIn
ldr r1, =0x02037FD4
ldrb r1, [r1, #7]
mov r2, #0x80
and r1, r2
cmp r1, #0
bne FadeInBack
ldr r1, =0x03005E00
mov r2, #40
mul r0, r2
add r0, r1
ldr r1, =(Task_ShowIVEVProcessInput|1)
str r1, [r0]
FadeInBack:
bx lr
.endfunc
.pool
.func Task_ShowIVEVProcessInput
push {r4-r5, lr}
add sp, #-4
ldr r1, =0x03005E00
mov r2, #40
mul r0, r2
add r5, r0, r1
ldr r0, =0x030022C0
ldrh r0, [r0, #0x2E]
cmp r0, #2
beq B_Pressed
cmp r0, #0x10
beq Right_Pressed
cmp r0, #0x20
beq Left_Pressed
b InputEnd
B_Pressed:
mov r0, #0
str r0, [sp]
neg r0, r0
mov r1, #0
mov r2, #0
mov r3, #0x10
ldr r4, =(0x080A1AD4|1)
bl call_bx2
ldr r0, =(Task_ShowIVEVFadeOut|1)
str r0, [r5]
b InputEnd
Right_Pressed:
ldrb r3, [r5, #8]
mov r1, r5
add r1, #8
ldrb r0, [r3, r1]
ldr r1, =0x02020630
mov r2, #0x44
mul r2, r0
add r1, r2
ldr r2, =(0x08007428|1)
str r2, [r1, #0x1C]
ldr r1, =0x020244E9
ldrb r1, [r1]
cmp r3, r1
bge BackToOne
add r3, #1
b RightNext
BackToOne:
mov r3, #1
RightNext:
strb r3, [r5, #8]
mov r1, r5
add r1, #8
ldrb r0, [r3, r1]
ldr r1, =0x02020630
mov r2, #0x44
mul r2, r0
add r1, r2
ldr r2, =(0x080D3014|1)
str r2, [r1, #0x1C]
sub r0, r3, #1
bl DrawMonIVEV
b InputEnd
Left_Pressed:
ldrb r3, [r5, #8]
mov r1, r5
add r1, #8
ldrb r0, [r3, r1]
ldr r1, =0x02020630
mov r2, #0x44
mul r2, r0
add r1, r2
ldr r2, =(0x08007428|1)
str r2, [r1, #0x1C]
mov r1, #1
cmp r3, r1
ble BackToMax
sub r3, #1
b LeftNext
BackToMax:
ldr r3, =0x020244E9
ldrb r3, [r3]
LeftNext:
strb r3, [r5, #8]
mov r1, r5
add r1, #8
ldrb r0, [r3, r1]
ldr r1, =0x02020630
mov r2, #0x44
mul r2, r0
add r1, r2
ldr r2, =(0x080D3014|1)
str r2, [r1, #0x1C]
sub r0, r3, #1
bl DrawMonIVEV
InputEnd:
add sp, #4
pop {r4-r5, pc}
.endfunc
.pool
.func Task_ShowIVEVFadeOut
push {lr}
ldr r1, =0x02037FD4
ldrb r1, [r1, #7]
mov r2, #0x80
and r1, r2
cmp r1, #0
bne FadeOutBack
ldr r3, =(0x080A909C|1)
bl call_bx
ldr r3, =(0x08003604|1)
bl call_bx
ldr r0, =0x030022C0
ldr r0, [r0, #8]
ldr r3, =(0x08000540|1)
bl call_bx
FadeOutBack:
pop {pc}
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.func call_bx2
bx r4
.endfunc
.pool
Switch:
.halfword (SetVBlankCallback - SetVBlankCallback + 1)
.halfword (InitBgsAndWindows - SetVBlankCallback + 1)
.halfword (ResetData - SetVBlankCallback + 1)
.halfword (LoadBoxTiles - SetVBlankCallback + 1)
.halfword (LoadWindowPalette - SetVBlankCallback + 1)
.halfword (LoadTextPalette - SetVBlankCallback + 1)
.halfword (DrawAndPutControl - SetVBlankCallback + 1)
.halfword (WaitState - SetVBlankCallback + 1)
.halfword (DrawAndPutMonIVEV - SetVBlankCallback + 1)
.halfword (FillBgTilemapBufferRects - SetVBlankCallback + 1)
.halfword (CreateSpritesAndTask - SetVBlankCallback + 1)
.halfword (FadeAndChangeCallBack - SetVBlankCallback + 1)
sShowEVIVBgTemplates:
BgTemplate 1, 1, 30, 0, 0, 0, 0
BgTemplate 0, 1, 31, 0, 0, 1, 0
sShowEVIVWinTemplates:
WindowTemplate 1, 2, 1, 26, 14, 1, 2
WindowTemplate 0, 2, 17, 26, 2, 1, 0x16E
WindowTemplate 0xFF, 0, 0, 0, 0, 0, 0
PoiX:
.byte 0x25, 0x45, 0x65, 0x85, 0xA5, 0xC5
gText_Control:
.string 0xF8, 0x08, 0xF8, 0x09, "选择精灵" , 0x00, 0xF8, 0x01, "退出"
gText_Frame:
.string 0xFC, 0x11, 0x1B, "HP", 0xFC, 0x11, 0x0E, "ATT DEF SPE SPA SPD\nIV\nEV"
gText_Blank:
.string " "
gText_LineFeed:
.string "\n"
Script_ShowEVIV:
lock
faceplayer
callasm (MainFunc|1)
waitstate
release
end
.org 0x089C0DFC
.word Script_ShowEVIV
.close

复制代码

整理控 · 发表于 2020-5-15 11:30:04

本站第一萌新 · 发表于 2020-5-15 22:45:43

整理控发表于 2020-5-15 11:30
666

谬赞了，这些都是入门级的东西。主要是考虑到论坛和编程有关的东西要不是过于基础要不是过于复杂才发这个帖子的。（虽然说现在有了老外的工程用ASM确实没多大意义了:(）

本站第一萌新 · 发表于 2020-5-16 09:04:54

扩充等级上限到150级（至于为什么不是200级或者更上是因为第二种经验类型的计算公式不支持高于160级，我也懒得自己去修改了。不过即使是只有150级也可能会有bug，如果发现的话请自行改写计算公式）

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.macro EXP_MEDIUM_FAST, level
.word level * level * level
.endmacro
.macro EXP_ERRATIC, level
.word (level <= 50) ? ((100 - level) * level * level * level / 50) : (level <= 68) ? ((150 - level) * level * level * level / 100) : (level <= 98) ? (((1911 - 10 * level) / 3) * level * level * level / 500) : ((160 - level) * level * level * level / 100)
.endmacro
.macro EXP_FLUCTUATING, level
.word (level <= 15) ? (((level + 1) / 3 + 24) * level * level * level / 50) : (level <= 36) ? ((level + 14) * level * level * level / 50) : (((level / 2) + 32) * level * level * level / 50)
.endmacro
.macro EXP_MEDIUM_SLOW, level
.word (6 * level * level * level) / 5 - (15 * level * level) + (100 * level) - 140
.endmacro
.macro EXP_FAST, level
.word 4 * (level * level * level) / 5
.endmacro
.macro EXP_SLOW, level
.word 5 * (level * level * level) / 4
.endmacro
.org 0x08F80000
.align 4
NewExpTable:
.incbin "test.gba", 0x31F72C, 0x194
EXP_MEDIUM_FAST 101
EXP_MEDIUM_FAST 102
EXP_MEDIUM_FAST 103
EXP_MEDIUM_FAST 104
EXP_MEDIUM_FAST 105
EXP_MEDIUM_FAST 106
EXP_MEDIUM_FAST 107
EXP_MEDIUM_FAST 108
EXP_MEDIUM_FAST 109
EXP_MEDIUM_FAST 110
EXP_MEDIUM_FAST 111
EXP_MEDIUM_FAST 112
EXP_MEDIUM_FAST 113
EXP_MEDIUM_FAST 114
EXP_MEDIUM_FAST 115
EXP_MEDIUM_FAST 116
EXP_MEDIUM_FAST 117
EXP_MEDIUM_FAST 118
EXP_MEDIUM_FAST 119
EXP_MEDIUM_FAST 120
EXP_MEDIUM_FAST 121
EXP_MEDIUM_FAST 122
EXP_MEDIUM_FAST 123
EXP_MEDIUM_FAST 124
EXP_MEDIUM_FAST 125
EXP_MEDIUM_FAST 126
EXP_MEDIUM_FAST 127
EXP_MEDIUM_FAST 128
EXP_MEDIUM_FAST 129
EXP_MEDIUM_FAST 130
EXP_MEDIUM_FAST 131
EXP_MEDIUM_FAST 132
EXP_MEDIUM_FAST 133
EXP_MEDIUM_FAST 134
EXP_MEDIUM_FAST 135
EXP_MEDIUM_FAST 136
EXP_MEDIUM_FAST 137
EXP_MEDIUM_FAST 138
EXP_MEDIUM_FAST 139
EXP_MEDIUM_FAST 140
EXP_MEDIUM_FAST 141
EXP_MEDIUM_FAST 142
EXP_MEDIUM_FAST 143
EXP_MEDIUM_FAST 144
EXP_MEDIUM_FAST 145
EXP_MEDIUM_FAST 146
EXP_MEDIUM_FAST 147
EXP_MEDIUM_FAST 148
EXP_MEDIUM_FAST 149
EXP_MEDIUM_FAST 150
.incbin "test.gba", 0x31F8C0, 0x194
EXP_ERRATIC 101
EXP_ERRATIC 102
EXP_ERRATIC 103
EXP_ERRATIC 104
EXP_ERRATIC 105
EXP_ERRATIC 106
EXP_ERRATIC 107
EXP_ERRATIC 108
EXP_ERRATIC 109
EXP_ERRATIC 110
EXP_ERRATIC 111
EXP_ERRATIC 112
EXP_ERRATIC 113
EXP_ERRATIC 114
EXP_ERRATIC 115
EXP_ERRATIC 116
EXP_ERRATIC 117
EXP_ERRATIC 118
EXP_ERRATIC 119
EXP_ERRATIC 120
EXP_ERRATIC 121
EXP_ERRATIC 122
EXP_ERRATIC 123
EXP_ERRATIC 124
EXP_ERRATIC 125
EXP_ERRATIC 126
EXP_ERRATIC 127
EXP_ERRATIC 128
EXP_ERRATIC 129
EXP_ERRATIC 130
EXP_ERRATIC 131
EXP_ERRATIC 132
EXP_ERRATIC 133
EXP_ERRATIC 134
EXP_ERRATIC 135
EXP_ERRATIC 136
EXP_ERRATIC 137
EXP_ERRATIC 138
EXP_ERRATIC 139
EXP_ERRATIC 140
EXP_ERRATIC 141
EXP_ERRATIC 142
EXP_ERRATIC 143
EXP_ERRATIC 144
EXP_ERRATIC 145
EXP_ERRATIC 146
EXP_ERRATIC 147
EXP_ERRATIC 148
EXP_ERRATIC 149
EXP_ERRATIC 150
.incbin "test.gba", 0x31FA54, 0x194
EXP_FLUCTUATING 101
EXP_FLUCTUATING 102
EXP_FLUCTUATING 103
EXP_FLUCTUATING 104
EXP_FLUCTUATING 105
EXP_FLUCTUATING 106
EXP_FLUCTUATING 107
EXP_FLUCTUATING 108
EXP_FLUCTUATING 109
EXP_FLUCTUATING 110
EXP_FLUCTUATING 111
EXP_FLUCTUATING 112
EXP_FLUCTUATING 113
EXP_FLUCTUATING 114
EXP_FLUCTUATING 115
EXP_FLUCTUATING 116
EXP_FLUCTUATING 117
EXP_FLUCTUATING 118
EXP_FLUCTUATING 119
EXP_FLUCTUATING 120
EXP_FLUCTUATING 121
EXP_FLUCTUATING 122
EXP_FLUCTUATING 123
EXP_FLUCTUATING 124
EXP_FLUCTUATING 125
EXP_FLUCTUATING 126
EXP_FLUCTUATING 127
EXP_FLUCTUATING 128
EXP_FLUCTUATING 129
EXP_FLUCTUATING 130
EXP_FLUCTUATING 131
EXP_FLUCTUATING 132
EXP_FLUCTUATING 133
EXP_FLUCTUATING 134
EXP_FLUCTUATING 135
EXP_FLUCTUATING 136
EXP_FLUCTUATING 137
EXP_FLUCTUATING 138
EXP_FLUCTUATING 139
EXP_FLUCTUATING 140
EXP_FLUCTUATING 141
EXP_FLUCTUATING 142
EXP_FLUCTUATING 143
EXP_FLUCTUATING 144
EXP_FLUCTUATING 145
EXP_FLUCTUATING 146
EXP_FLUCTUATING 147
EXP_FLUCTUATING 148
EXP_FLUCTUATING 149
EXP_FLUCTUATING 150
.incbin "test.gba", 0x31FBE8, 0x194
EXP_MEDIUM_SLOW 101
EXP_MEDIUM_SLOW 102
EXP_MEDIUM_SLOW 103
EXP_MEDIUM_SLOW 104
EXP_MEDIUM_SLOW 105
EXP_MEDIUM_SLOW 106
EXP_MEDIUM_SLOW 107
EXP_MEDIUM_SLOW 108
EXP_MEDIUM_SLOW 109
EXP_MEDIUM_SLOW 110
EXP_MEDIUM_SLOW 111
EXP_MEDIUM_SLOW 112
EXP_MEDIUM_SLOW 113
EXP_MEDIUM_SLOW 114
EXP_MEDIUM_SLOW 115
EXP_MEDIUM_SLOW 116
EXP_MEDIUM_SLOW 117
EXP_MEDIUM_SLOW 118
EXP_MEDIUM_SLOW 119
EXP_MEDIUM_SLOW 120
EXP_MEDIUM_SLOW 121
EXP_MEDIUM_SLOW 122
EXP_MEDIUM_SLOW 123
EXP_MEDIUM_SLOW 124
EXP_MEDIUM_SLOW 125
EXP_MEDIUM_SLOW 126
EXP_MEDIUM_SLOW 127
EXP_MEDIUM_SLOW 128
EXP_MEDIUM_SLOW 129
EXP_MEDIUM_SLOW 130
EXP_MEDIUM_SLOW 131
EXP_MEDIUM_SLOW 132
EXP_MEDIUM_SLOW 133
EXP_MEDIUM_SLOW 134
EXP_MEDIUM_SLOW 135
EXP_MEDIUM_SLOW 136
EXP_MEDIUM_SLOW 137
EXP_MEDIUM_SLOW 138
EXP_MEDIUM_SLOW 139
EXP_MEDIUM_SLOW 140
EXP_MEDIUM_SLOW 141
EXP_MEDIUM_SLOW 142
EXP_MEDIUM_SLOW 143
EXP_MEDIUM_SLOW 144
EXP_MEDIUM_SLOW 145
EXP_MEDIUM_SLOW 146
EXP_MEDIUM_SLOW 147
EXP_MEDIUM_SLOW 148
EXP_MEDIUM_SLOW 149
EXP_MEDIUM_SLOW 150
.incbin "test.gba", 0x31FD7C, 0x194
EXP_FAST 101
EXP_FAST 102
EXP_FAST 103
EXP_FAST 104
EXP_FAST 105
EXP_FAST 106
EXP_FAST 107
EXP_FAST 108
EXP_FAST 109
EXP_FAST 110
EXP_FAST 111
EXP_FAST 112
EXP_FAST 113
EXP_FAST 114
EXP_FAST 115
EXP_FAST 116
EXP_FAST 117
EXP_FAST 118
EXP_FAST 119
EXP_FAST 120
EXP_FAST 121
EXP_FAST 122
EXP_FAST 123
EXP_FAST 124
EXP_FAST 125
EXP_FAST 126
EXP_FAST 127
EXP_FAST 128
EXP_FAST 129
EXP_FAST 130
EXP_FAST 131
EXP_FAST 132
EXP_FAST 133
EXP_FAST 134
EXP_FAST 135
EXP_FAST 136
EXP_FAST 137
EXP_FAST 138
EXP_FAST 139
EXP_FAST 140
EXP_FAST 141
EXP_FAST 142
EXP_FAST 143
EXP_FAST 144
EXP_FAST 145
EXP_FAST 146
EXP_FAST 147
EXP_FAST 148
EXP_FAST 149
EXP_FAST 150
.incbin "test.gba", 0x31FF10, 0x194
EXP_SLOW 101
EXP_SLOW 102
EXP_SLOW 103
EXP_SLOW 104
EXP_SLOW 105
EXP_SLOW 106
EXP_SLOW 107
EXP_SLOW 108
EXP_SLOW 109
EXP_SLOW 110
EXP_SLOW 111
EXP_SLOW 112
EXP_SLOW 113
EXP_SLOW 114
EXP_SLOW 115
EXP_SLOW 116
EXP_SLOW 117
EXP_SLOW 118
EXP_SLOW 119
EXP_SLOW 120
EXP_SLOW 121
EXP_SLOW 122
EXP_SLOW 123
EXP_SLOW 124
EXP_SLOW 125
EXP_SLOW 126
EXP_SLOW 127
EXP_SLOW 128
EXP_SLOW 129
EXP_SLOW 130
EXP_SLOW 131
EXP_SLOW 132
EXP_SLOW 133
EXP_SLOW 134
EXP_SLOW 135
EXP_SLOW 136
EXP_SLOW 137
EXP_SLOW 138
EXP_SLOW 139
EXP_SLOW 140
EXP_SLOW 141
EXP_SLOW 142
EXP_SLOW 143
EXP_SLOW 144
EXP_SLOW 145
EXP_SLOW 146
EXP_SLOW 147
EXP_SLOW 148
EXP_SLOW 149
EXP_SLOW 150
.incbin "test.gba", 0x31F72C, 0x194 ;不知道有什么用，但原版就是这样的
EXP_MEDIUM_FAST 101
EXP_MEDIUM_FAST 102
EXP_MEDIUM_FAST 103
EXP_MEDIUM_FAST 104
EXP_MEDIUM_FAST 105
EXP_MEDIUM_FAST 106
EXP_MEDIUM_FAST 107
EXP_MEDIUM_FAST 108
EXP_MEDIUM_FAST 109
EXP_MEDIUM_FAST 110
EXP_MEDIUM_FAST 111
EXP_MEDIUM_FAST 112
EXP_MEDIUM_FAST 113
EXP_MEDIUM_FAST 114
EXP_MEDIUM_FAST 115
EXP_MEDIUM_FAST 116
EXP_MEDIUM_FAST 117
EXP_MEDIUM_FAST 118
EXP_MEDIUM_FAST 119
EXP_MEDIUM_FAST 120
EXP_MEDIUM_FAST 121
EXP_MEDIUM_FAST 122
EXP_MEDIUM_FAST 123
EXP_MEDIUM_FAST 124
EXP_MEDIUM_FAST 125
EXP_MEDIUM_FAST 126
EXP_MEDIUM_FAST 127
EXP_MEDIUM_FAST 128
EXP_MEDIUM_FAST 129
EXP_MEDIUM_FAST 130
EXP_MEDIUM_FAST 131
EXP_MEDIUM_FAST 132
EXP_MEDIUM_FAST 133
EXP_MEDIUM_FAST 134
EXP_MEDIUM_FAST 135
EXP_MEDIUM_FAST 136
EXP_MEDIUM_FAST 137
EXP_MEDIUM_FAST 138
EXP_MEDIUM_FAST 139
EXP_MEDIUM_FAST 140
EXP_MEDIUM_FAST 141
EXP_MEDIUM_FAST 142
EXP_MEDIUM_FAST 143
EXP_MEDIUM_FAST 144
EXP_MEDIUM_FAST 145
EXP_MEDIUM_FAST 146
EXP_MEDIUM_FAST 147
EXP_MEDIUM_FAST 148
EXP_MEDIUM_FAST 149
EXP_MEDIUM_FAST 150
.incbin "test.gba", 0x31F72C, 0x194
EXP_MEDIUM_FAST 101
EXP_MEDIUM_FAST 102
EXP_MEDIUM_FAST 103
EXP_MEDIUM_FAST 104
EXP_MEDIUM_FAST 105
EXP_MEDIUM_FAST 106
EXP_MEDIUM_FAST 107
EXP_MEDIUM_FAST 108
EXP_MEDIUM_FAST 109
EXP_MEDIUM_FAST 110
EXP_MEDIUM_FAST 111
EXP_MEDIUM_FAST 112
EXP_MEDIUM_FAST 113
EXP_MEDIUM_FAST 114
EXP_MEDIUM_FAST 115
EXP_MEDIUM_FAST 116
EXP_MEDIUM_FAST 117
EXP_MEDIUM_FAST 118
EXP_MEDIUM_FAST 119
EXP_MEDIUM_FAST 120
EXP_MEDIUM_FAST 121
EXP_MEDIUM_FAST 122
EXP_MEDIUM_FAST 123
EXP_MEDIUM_FAST 124
EXP_MEDIUM_FAST 125
EXP_MEDIUM_FAST 126
EXP_MEDIUM_FAST 127
EXP_MEDIUM_FAST 128
EXP_MEDIUM_FAST 129
EXP_MEDIUM_FAST 130
EXP_MEDIUM_FAST 131
EXP_MEDIUM_FAST 132
EXP_MEDIUM_FAST 133
EXP_MEDIUM_FAST 134
EXP_MEDIUM_FAST 135
EXP_MEDIUM_FAST 136
EXP_MEDIUM_FAST 137
EXP_MEDIUM_FAST 138
EXP_MEDIUM_FAST 139
EXP_MEDIUM_FAST 140
EXP_MEDIUM_FAST 141
EXP_MEDIUM_FAST 142
EXP_MEDIUM_FAST 143
EXP_MEDIUM_FAST 144
EXP_MEDIUM_FAST 145
EXP_MEDIUM_FAST 146
EXP_MEDIUM_FAST 147
EXP_MEDIUM_FAST 148
EXP_MEDIUM_FAST 149
EXP_MEDIUM_FAST 150
.org 0x08067CF0
mov r0, #151
lsl r0, #2
.org 0x08069082
mov r5, #151
lsl r5, #2
.org 0x080690EE
mov r5, #151
lsl r5, #2
.org 0x0806C1A8
mov r0, #151
lsl r0, #2
.org 0x0806DFB2
mov r1, #151
lsl r1, #2
.org 0x0806DFBA
mov r2, #150
lsl r2, #2
.org 0x08059240
mov r1, #151
lsl r1, #2
.org 0x080593A0
mov r0, #151
lsl r0, #2
.org 0x080594A8
mov r0, #151
lsl r0, #2
.org 0x081BB324
mov r1, #151
lsl r1, #2
.org 0x081BB484
mov r0, #151
lsl r0, #2
.org 0x081BB58C
mov r0, #151
lsl r0, #2
.org 0x0807499C
mov r0, #151
lsl r0, #2
.org 0x081A7C70
mov r1, #151
lsl r1, #2
.org 0x081A9D10
mov r0, #151
lsl r0, #2
.org 0x081661CA
mov r0, #151
lsl r0, #2
.org 0x081C22FC
mov r0, #151
lsl r0, #2
.org 0x081C3922
mov r0, #151
lsl r0, #2
.org 0x081D6458
mov r0, #151
lsl r0, #2
.org 0x081C3908
cmp r0, #149
.org 0x081C22E2
cmp r1, #149
.org 0x08069096
cmp r2, #150
.org 0x08069102
cmp r2, #150
.org 0x0806C17C
cmp r0, #150
.org 0x0806DFD8
cmp r0, #150
.org 0x0805C54A
cmp r0, #149
.org 0x081BDD22
cmp r0, #149
.org 0x08074CDE
cmp r0, #149
.org 0x08E103E0 ;如果是绿宝石802，使用这一条
cmp r0, #149
; .org 0x0804A5BE ;如果是原版绿宝石，使用这两条(未经测试，如果发现bug请告知于我)
; cmp r0, #150
;
; .org 0x0804A88E
; cmp r0, #150
.org 0x0806FD20
cmp r0, #150
.org 0x0806FCE4
cmp r5, #149
.org 0x081B743A
cmp r0, #150
.org 0x080592C4
.word NewExpTable
.org 0x080593F0
.word NewExpTable
.org 0x08059500
.word NewExpTable
.org 0x08067DC0
.word NewExpTable
.org 0x080690B8
.word NewExpTable
.org 0x08069124
.word NewExpTable
.org 0x0806C2E4
.word NewExpTable
.org 0x0806DFF0
.word NewExpTable
.org 0x08074A10
.word NewExpTable
.org 0x081661FC
.word NewExpTable
.org 0x081A7CFC
.word NewExpTable
.org 0x081A9D48
.word NewExpTable
.org 0x081BB3A8
.word NewExpTable
.org 0x081BB4D4
.word NewExpTable
.org 0x081BB5E4
.word NewExpTable
.org 0x081C2338
.word NewExpTable
.org 0x081C3940
.word NewExpTable
.org 0x081D6488
.word NewExpTable
.close

复制代码

本站第一萌新 · 发表于 2020-5-16 21:39:13

适用于绿宝石802 3.0版本
没啥东西想整了，做点小修复吧。修复802大师球必定抓捕

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func FixMasterBall
cmp r0, #4
bne Normal
mov r0, #1
neg r0, r0
bx lr
Normal:
ldr r3, =0x080001BC
push {r0-r2, r4-r7, lr}
ldr r2, [r3]
mov r3, #0x1C
ldr r5, =(0x08E14028|1)
bx r5
.endfunc
.pool
.org 0x08E14020
ldr r3, =(FixMasterBall|1)
bx r3
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-16 21:55:19

本帖最后由本站第一萌新于 2020-5-16 21:56 编辑

适用于绿宝石802 3.0版本
添加梦特性系统。这是从我之前的工程里挖出来的代码了。现在看来有更好的实现方式（比如究极绿的实现方式就十分巧妙和高效），不过也懒得改了（没错，就是这么懒）。想研究的自己去分析吧

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func PrintAbilityHack
add r1, #0x78
ldr r2, =0x0203CF1C
ldr r2, [r2]
add r2, #0xC
bl CheckIsDreamAbility
cmp r2, #0
bne PrintAbilityHackBack
ldrb r1, [r1]
ldr r3, =(0x0806B694|1)
bl call_bx
PrintAbilityHackBack:
mov r4, r0
ldr r3, =(0x081C2FEE|1)
bx r3
.endfunc
.pool
.func PrintDescriptionHack
ldrh r0, [r0]
add r1, #0x78
ldr r2, =0x0203CF1C
ldr r2, [r2]
add r2, #0xC
bl CheckIsDreamAbility
cmp r2, #0
bne PrintDescriptionHackBack
ldrb r1, [r1]
ldr r3, =(0x0806B694|1)
bl call_bx
PrintDescriptionHackBack:
ldr r3, =(0x081C3042|1)
bx r3
.endfunc
.pool
.func LoadAbilityHack1
bl LoadAbilityHack
ldr r3, =(0x0803AD6C|1)
bx r3
.endfunc
.pool
.func LoadAbilityHack2
bl LoadAbilityHack
ldrb r1, [r6]
ldr r3, =(0x0804C9A0|1)
bx r3
.endfunc
.pool
.func LoadAbilityHack
ldrb r1, [r1, #0x17]
lsr r1, r1, #7
push {r4-r5, lr}
mov r4, r0
mov r5, r1
ldr r0, =0x02024064
ldrb r0, [r0]
ldr r3, =(0x08E1833C|1)
bl call_bx
mov r2, r0
mov r0, r4
bl CheckIsDreamAbility
cmp r2, #0
bne LoadAbilityHackBack
mov r0, r4
mov r1, r5
ldr r3, =(0x0806B694|1)
bl call_bx
LoadAbilityHackBack:
pop {r4-r5, pc}
.endfunc
.pool
.func CheckIsDreamAbility
add r2, #0x13
ldrb r2, [r2]
mov r3, #8
and r2, r3
cmp r2, #0
beq CheckIsDreamAbilityBack
ldr r1, =(0x08F186E0 + 0x1A)
mov r2, #0x1C
mul r0, r2
add r0, r1
ldrb r0, [r0]
CheckIsDreamAbilityBack:
bx lr
.endfunc
.pool
.func RandomToHaveDreamAbility
mov r4, r0
ldr r3, =(0x08069270|1)
bl call_bx
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r1, #3
ldr r3, =(0x082E7BE0|1)
bl call_bx
cmp r0, #0
bne RandomToHaveDreamAbilityBack
add r4, #0x13
ldrb r0, [r4]
mov r1, #8
orr r0, r1
strb r0, [r4]
RandomToHaveDreamAbilityBack:
add sp, #0x20
pop {r3-r5}
mov r8, r3
ldr r3, =(0x08067E82|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x081C2FE6
ldr r3, =(PrintAbilityHack|1)
bx r3
.pool
.org 0x081C3038
ldr r3, =(PrintDescriptionHack|1)
bx r3
.pool
.org 0x0803AD64
ldr r3, =(LoadAbilityHack1|1)
bx r3
.pool
.org 0x0804C996
ldr r3, =(LoadAbilityHack2|1)
bx r3
.pool
.org 0x08067E78
ldr r3, =(RandomToHaveDreamAbility|1)
bx r3
.pool
.org 0x08F186E0 ;导入梦特性，貌似还会导入几只新精灵（当然是没图的，仅仅是数据而已）。不过影响不大。如果你实在不想让这一现象发生的话，请自行更改0x75B0
.incbin "files/files.bin", 0x320, 0x75B0
.close

复制代码

files这个文件是我当时为了把数据和源码绑在一起创建的一个文件，里面有新精灵图片，梦特数据等等各种乱七八糟的东西。

本站第一萌新 · 发表于 2020-5-16 22:03:08

适用于绿宝石802 3.0版本
一样从之前的工程里挖出来的代码，添加睡眠条款和冰冻条款
这个几乎未经测试，如果发现bug请通知于我，我有时间可能会尝试修复

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func SleepClause
push {r0-r2, r4-r7, lr}
mov r4, r0
mov r5, r1
mov r1, #3
bl CheckClause
cmp r0, #0
bne CantGetSleep
mov r1, r5
mov r0, r4
mov r4, #0x58
mul r4, r0
ldr r3, =0x02024084
ldr r2, =(0x08E07BAC|1)
bx r2
CantGetSleep:
mov r0, #3
pop {r1-r7, pc}
.endfunc
.pool
.func FreezeClause
push {r3-r7, lr}
mov r4, r0
mov r5, r1
mov r1, #4
bl CheckClause
cmp r0, #0
bne CantGetFreeze
mov r1, r5
mov r0, r4
mov r3, #0x58
mul r3, r0
ldr r4, =0x02024084
ldr r3, =(0x08E07E04|1)
bx r3
CantGetFreeze:
mov r0, #3
pop {r3-r7, pc}
.endfunc
.pool
.func CheckClause
push {r4-r6,lr}
mov r5, #0
mov r6, r1
ldr r3, =(0x08E0736C|1)
bl call_bx
ldr r4, =0x020244EC
cmp r0, #1
bne CheckClauseLoop
ldr r4, =0x02024744
CheckClauseLoop:
mov r0, r4
mov r1, #100
mul r1, r5
add r0, r1
ldr r3, =(0x081B205C|1)
bl call_bx
cmp r0, r6
beq CheckClauseLoopEnd
add r5, #1
cmp r5, #6
blt CheckClauseLoop
CheckClauseLoopEnd:
mov r0, #0
cmp r5, #6
beq CantGetStatu
mov r0, #1
CantGetStatu:
pop {r4-r6, pc}
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x08E07BA4
ldr r3, =(SleepClause|1)
bx r3
.pool
.org 0x08E07DFC
ldr r3, =(FreezeClause|1)
bx r3
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-17 10:10:46

前阵子全随机模式比较火啊，于是我就随便搞了一个。我不清楚那个全随机到底是什么东西，因为我没玩过，不过我搞的这是真正的全随机，不管是草丛里遇到的，NPC给的，甚至是对战训练师的精灵也是随机的。

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func GetRandomPoke
add r6, sp, #0x10
strb r2, [r6]
push {r0, r3}
ldr r3, =(0x0806F5CC|1)
bl call_bx
ldr r1, =0x42D ;改成你版本精灵数减一
ldr r3, =(0x082E7650|1)
bl call_bx
add r1, r0, #1
pop {r0, r3}
add r5, sp
strh r1, [r5]
ldr r5, =(0x08067BD8|1)
bx r5
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x08067BD0
ldr r6, =(GetRandomPoke|1)
bx r6
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-17 10:44:52

不遇敌，一样与初始村蓝胖对话查看效果

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func NoEnemies
push {r4-r6, lr}
lsl r0, r0, #0x18
lsr r6, r0, #0x18
ldr r0, =0x4012
ldr r3, =(0x0809D790|1)
bl call_bx
cmp r0, #0
beq CheckNext
mov r0, #0
pop {r4-r6, pc}
CheckNext:
ldr r0, =0x4021
ldr r3, =(0x080B58D4|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
Script_NoEnemies:
lock
faceplayer
checkflag 0x4012
if1 0x0, Script_Open
clearflag 0x4012
msgbox gText_Close, 0x6
release
end
Script_Open:
setflag 0x4012
msgbox gText_Open, 0x6
release
end
gText_Close:
.string "关闭不遇敌！"
gText_Open:
.string "打开不遇敌！"
.org 0x080B58CC
ldr r3, =(NoEnemies|1)
bx r3
.pool
.org 0x089C0DFC
.word Script_NoEnemies
.close

复制代码

本站第一萌新 · 发表于 2020-5-23 20:09:11

本帖最后由本站第一萌新于 2020-5-24 08:19 编辑

久违的更新
最近在贴吧看到个火箭队改版，打败训练师之后可以抢夺的一只精灵。觉得挺有意思就模仿了一个。不过他那个是用的多选框实现的，感觉太low了。我这个使用队伍界面实现。
注意：这个例程只能抢普通训练师的精灵，抢不了带脚本训练师的精灵（我只试验了新手档小遥）。如果想要实现抢这些训练师的精灵请自行去修改。不过我感觉作为一个反派只会欺凌弱小没啥问题（其实就是懒得搞

）

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func InitRobPartyMenu
push {r4, lr}
add sp, #-12
ldr r3, =(0x08076D8C|1)
bl call_bx
ldr r0, =0x020244EC
ldr r1, =0x02024744
mov r2, #150
lsl r2, #2
ldr r3, =(0x0806B408|1)
bl call_bx
mov r0, #0
str r0, [sp]
ldr r1, =(0x081B1370|1)
str r1, [sp, #4]
ldr r1, =(0x080861CC|1)
str r1, [sp, #8]
mov r1, #0
mov r2, #14
mov r3, #0
ldr r4, =(0x081B0038|1)
bl call_bx2
add sp, #12
pop {r4, pc}
.endfunc
.pool
.func CaseRob
mov r0, #5
ldr r3, =(0x080A37A4|1)
bl call_bx
mov r0, r5
bl CreateWinAndFunc
pop {r4-r5, pc}
.endfunc
.pool
.func CreateWinAndFunc
push {lr}
ldr r2, =0x03005E00
mov r1, #40
mul r1, r0
add r1, r2
mov r0, #0xFF
strh r0, [r1, #8]
ldr r0, =(0x081B3730|1)
str r0, [r1]
bl CreateWindow
pop {pc}
.endfunc
.pool
.func CreateWindow
push {lr}
ldr r0, =0x0203CEC4
ldr r0, [r0]
add r0, #13
ldr r3, =(0x081B302C|1)
bl call_bx
ldr r0, =0x020244EC
ldr r1, =0x0203CEC8
ldrb r1, [r1, #9]
mov r2, #14
ldr r3, =(0x081B33B4|1)
bl call_bx
mov r0, #0
ldr r3, =(0x081B31B0|1)
bl call_bx
mov r0, #21
ldr r3, =(0x081B3054|1)
bl call_bx
pop {pc}
.endfunc
.pool
.func CursorCb_Rob
push {r4-r5, lr}
mov r4, r0
ldr r3, =(0x08076DD4|1)
bl call_bx
ldr r0, =0x0203CEC8
ldrb r0, [r0, #9]
ldr r1, =0x02024744
mov r2, #100
mul r0, r2
add r0, r1
mov r5, r0
ldr r3, =(0x0806B414|1)
bl call_bx
mov r0, r5
mov r1, #2
ldr r2, =0x02021CC4
ldr r3, =(0x0806A518|1)
bl call_bx
mov r0, r4
ldr r3, =(0x081B12C0|1)
bl call_bx
pop {r4-r5, pc}
.endfunc
.pool
.func CheckIsRob
mov r1, #21
str r1, [sp]
cmp r2, #14
beq IsRob
ldr r1, =(0x081B36FC|1)
b CheckBack
IsRob:
ldr r1, =(CreateWinAndFunc|1)
CheckBack:
str r1, [sp, #4]
ldr r1, [r3]
ldr r3, =(0x081B38BC|1)
bx r3
.endfunc
.pool
.func CheckCanExit
ldr r0, =0x0203CEC8
ldrb r0, [r0, #11]
cmp r0, #8
beq GotoSub81B1602
cmp r0, #14
beq CantExit
ldr r3, =(0x081B15E0|1)
bx r3
GotoSub81B1602:
ldr r3, =(0x081B1602|1)
bx r3
CantExit:
ldr r3, =(0x081B15FB|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.func call_bx2
bx r4
.endfunc
.pool
.align 4
NewSwitchTable:
.incbin "test.gba", 0x1B144C, 0x2C
.word (CaseRob|1)
.align 4
NewActionTable:
.incbin "test.gba", 0x615D38, 0x38
.word ActionRob
NewListSizeTable:
.incbin "test.gba", 0x615D70, 0x0E
.byte 0x03
.align 4
NewCursorOptions:
.incbin "test.gba", 0x615C08, 0x108
.word gText_Rob
.word (CursorCb_Rob|1)
ActionRob:
.byte 0, 33, 2
Script_EndTrainerBattle:
callasm (InitRobPartyMenu|1)
waitstate
msgbox gText_RobPoke, 6
endtrainerbattle2
releaseall
end
gText_Rob:
.string 0xFC, 0x01, 0x04, "抢夺"
gText_RobPoke:
.string "[文本色_红]抢到了[buffer1]!"
.org 0x08271461
.word Script_EndTrainerBattle
.org 0x0827146C
.word Script_EndTrainerBattle
.org 0x08271477
.word Script_EndTrainerBattle
.org 0x08271482
.word Script_EndTrainerBattle
.org 0x0827148D
.word Script_EndTrainerBattle
.org 0x081B1432
cmp r0, #11
.org 0x081B1448
.word NewSwitchTable
.org 0x081B340C
.word NewListSizeTable
.word NewActionTable
.org 0x081B32F8
.word NewCursorOptions
.org 0x081B37C8
.word NewCursorOptions
.org 0x081B37F8
.word NewCursorOptions
.org 0x081B38B4
ldr r1, =(CheckIsRob|1)
bx r1
.pool
.org 0x081B15D8
ldr r3, =(CheckCanExit|1)
bx r3
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-24 13:54:47

本帖最后由本站第一萌新于 2020-5-24 14:09 编辑

看最近老外的不少改版都添加了明雷系统，我就也搞了一个。本质就是定点加行走图加取消草丛遇怪，不过我添加了浮动等级和随机携带道具（定义在精灵数据里的道具）。至于行走图自行添加。我不知道老外是不是这样的，不过想来估计也是大同小异吧

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func BrightRay
push {r4, lr}
ldr r3, =(0x0806F5CC|1)
bl call_bx
ldr r2, =0x020375E0
ldrb r1, [r2, #2]
ldrb r4, [r2, #3]
sub r1, r4
add r1, #1
ldr r3, =(0x082E7650|1)
bl call_bx
add r4, r0
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r1, #1
and r0, r1
lsl r0, #1
add r0, #12
ldr r1, =0x020375E0
ldrh r1, [r1]
ldr r2, =0x08F186E0 ;802 3.0版本不改。原版绿宝石将此处改成0x1BC下的地址
mov r3, #0x1C
mul r3, r1
add r3, r2
ldrh r2, [r0, r3]
mov r0, r1
mov r1, r4
ldr r3, =(0x080F93A0|1)
bl call_bx
ldr r3, =(0x080B08A8|1)
bl call_bx
ldr r3, =(0x08098F30|1)
bl call_bx
pop {r4, pc}
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
Script_BrightRay:
lock
faceplayer
msgbox gText_BrightRay, 6
callasm (BrightRay|1)
waitstate
hidesprite 0x800F
fadescreen 1
fadescreen 0
msgbox gText_PokeEscape, 6
release
return
gText_BrightRay:
.string "...？"
gText_PokeEscape:
.string "精灵消失不见。"
.org 0x080B58CC
mov r0, #0
bx lr
.close

复制代码

示例脚本：
setvar 0x8004 1 //精灵种类，如此处我用的妙蛙种子
setvar 0x8005 0x305 //最低等级和最高等级的拼接，如此处我用的3-5级
call 0xF80080
end

本站第一萌新 · 发表于 2020-5-28 12:49:04

本帖最后由本站第一萌新于 2020-5-30 10:39 编辑

去除原版绿宝石精灵加密和合法性检测

.gba
.thumb
.create "绿宝石.gba",0x8000000
.close
.open "BPEE.gba","绿宝石.gba", 0x8000000
.org 0x0806A236
nop
.org 0x0806A23C
nop
.org 0x0806A25A
nop
.org 0x0806A260
nop
.org 0x0806ADFE
b 0x0806AE1C
.org 0x0806A6DA
b 0x0806A6F2
.org 0x0806A27C
mov r0, #0
nop
nop
.close

复制代码

		自动登录	找回密码
密码			加入口袋中心